home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1997 #1 / Amiga Plus CD - 1997 - No. 01.iso / pd / programmierung / proasm / routines / tasktricks.r < prev    next >
Text File  |  1995-04-15  |  16KB  |  926 lines
  1.  
  2. ;---;  tasktricks.r  ;-------------------------------------------------------------
  3. *
  4. *    ****    SOME NIFTY LITTLE ROUTINES FOR TASKS    ****
  5. *
  6. *    Author        Stefan Walter
  7. *    Add. Code    Daniel Weber
  8. *    Version        1.16
  9. *    Last Revision    13.06.93
  10. *    Identifier    ttr_defined
  11. *    Prefix        ttr_    (task tricks)
  12. *                 ¯    ¯¯
  13. *    Macros        GetTaskPCPtr_, Forbid_, Permit_, Disable_, Enable_
  14. *            Supervisor_, GetCCR_, GetSR_, FindTask_, FindName_
  15. *            GetVBR_, User_, ClearCaches_, PrevState_
  16. *            DoRaw_, DoRawCnt_, InitList_, RestoreTDID_, SpaceKiller_,
  17. *            NoReq_, SetReq_, RestoreReq_
  18. *
  19. ;------------------------------------------------------------------------------
  20.  
  21. ;------------------
  22.     ifnd    ttr_defined
  23. ttr_defined    =1
  24.  
  25. ;------------------
  26. ttr_oldbase    equ __base
  27.     base    ttr_base
  28. ttr_base:
  29.  
  30. ;------------------
  31.  
  32. ;------------------------------------------------------------------------------
  33. *
  34. * GetTaskPCPtr_    Get address of PC in the stack of a task which is
  35. *        ready or waiting, concidering FPU frames on stack.
  36. *        If attempted on thistask, 0 is returned.
  37. *
  38. * INPUT:    a0    Task address
  39. *
  40. * RESULT:    a0    Pointer to address where PC is stored or 0.
  41. *
  42. * NOTE:        a0+0.l        =PC        a0+4.w        =SR
  43. *        a0+6+n*4.l    =Dn        a0+38+n*4.l    =An (exc. a7)
  44. *
  45. ;------------------------------------------------------------------------------
  46.  
  47. ;------------------
  48. ; Macro
  49. ;
  50. GetTaskPCPtr_    macro
  51.     ifd    ttr_GetTaskPCPtr
  52.         bsr    ttr_GetTaskPCPtr
  53.     else
  54.         pea    .ttr_end1(pc)
  55.  
  56. ;------------------
  57. ; Check for presence of FPU.
  58. ;
  59. ttr_GetTaskPCPtr    =    *
  60.     movem.l    d0/a6,-(sp)
  61.     move.l    4.w,a6
  62.     cmp.l    $114(a6),a0
  63.     beq.s    .ttr_task1
  64.     move.l    54(a0),a0    ;SP
  65.     btst    #4,297(a6)    ;FPU 81/82?
  66.     beq.s    .ttr_exit1
  67.  
  68.  
  69. ;------------------
  70. ; FPU present, check frame size.
  71. ;
  72. .ttr_fpu1:
  73.     move.b    (a0),d0
  74.     beq.s    .ttr_nos1
  75.  
  76.     lea    (2+4*3+12*8)(a0),a0
  77.     cmp.b    #$90,d0
  78.     bne.s    .ttr_nos1
  79.     lea    4*3+2(a0),a0
  80.  
  81. .ttr_nos1:
  82.     moveq    #4,d0            ;frame size for NULL frame
  83.     tst.b    (a0)
  84.     beq.s    .ttr_gotit1
  85.     move.b    1(a0),d0        ;fpu frame size
  86.  
  87. .ttr_gotit1:
  88.     add.w    d0,a0
  89.  
  90.  
  91.  
  92. ;------------------
  93. ; Got pointer and go.
  94. ;
  95. .ttr_exit1:
  96.     movem.l    (sp)+,d0/a6
  97.     rts
  98.  
  99. .ttr_task1:
  100.     suba.l    a0,a0
  101.     bra.s    .ttr_exit1
  102.  
  103. ;------------------
  104. ; End of macro.
  105. ;
  106. .ttr_end1:
  107.     endif
  108.     endm
  109.  
  110. ;------------------
  111.  
  112. ;------------------------------------------------------------------------------
  113. *
  114. * Forbid_    Call Forbid(). No registers changed.
  115. *
  116. ;------------------------------------------------------------------------------
  117.  
  118. ;------------------
  119. ; Macro
  120. ;
  121. Forbid_        macro
  122.     ifd    ttr_Forbid
  123.         bsr    ttr_Forbid
  124.     else
  125.         pea    .ttr_end2(pc)
  126.  
  127. ;------------------
  128. ; Forbid().
  129. ;
  130. ttr_Forbid    =    *
  131.     move.l    a6,-(sp)
  132.     move.l    4.w,a6
  133.     jsr    -132(a6)        ;Forbid()
  134.     move.l    (sp)+,a6
  135.     rts
  136.  
  137. ;------------------
  138. ; End of macro.
  139. ;
  140. .ttr_end2:
  141.     endif
  142.     endm
  143.  
  144. ;------------------
  145.  
  146. ;------------------------------------------------------------------------------
  147. *
  148. * Permit_    Call Permit(). No registers changed.
  149. *
  150. ;------------------------------------------------------------------------------
  151.  
  152. ;------------------
  153. ; Macro
  154. ;
  155. Permit_        macro
  156.     ifd    ttr_Permit
  157.         bsr    ttr_Permit
  158.     else
  159.         pea    .ttr_end3(pc)
  160.  
  161. ;------------------
  162. ; Permit().
  163. ;
  164. ttr_Permit    =    *
  165.     move.l    a6,-(sp)
  166.     move.l    4.w,a6
  167.     jsr    -138(a6)        ;Permit()
  168.     move.l    (sp)+,a6
  169.     rts
  170.  
  171. ;------------------
  172. ; End of macro.
  173. ;
  174. .ttr_end3:
  175.     endif
  176.     endm
  177.  
  178. ;------------------
  179.  
  180. ;------------------------------------------------------------------------------
  181. *
  182. * Disable_    Call Disable(). No registers changed.
  183. *
  184. ;------------------------------------------------------------------------------
  185.  
  186. ;------------------
  187. ; Macro
  188. ;
  189. Disable_    macro
  190.     ifd    ttr_Disable
  191.         bsr    ttr_Disable
  192.     else
  193.         pea    .ttr_end4(pc)
  194.  
  195. ;------------------
  196. ; Disable().
  197. ;
  198. ttr_Disable    =    *
  199.     move.l    a6,-(sp)
  200.     move.l    4.w,a6
  201.     jsr    -120(a6)        ;Disable()
  202.     move.l    (sp)+,a6
  203.     rts
  204.  
  205. ;------------------
  206. ; End of macro.
  207. ;
  208. .ttr_end4:
  209.     endif
  210.     endm
  211.  
  212. ;------------------
  213.  
  214. ;------------------------------------------------------------------------------
  215. *
  216. * Enable_    Call Enable(). No registers changed.
  217. *
  218. ;------------------------------------------------------------------------------
  219.  
  220. ;------------------
  221. ; Macro
  222. ;
  223. Enable_        macro
  224.     ifd    ttr_Enable
  225.         bsr    ttr_Enable
  226.     else
  227.         pea    .ttr_end5(pc)
  228.  
  229. ;------------------
  230. ; Enable().
  231. ;
  232. ttr_Enable    =    *
  233.     move.l    a6,-(sp)
  234.     move.l    4.w,a6
  235.     jsr    -126(a6)        ;Enable()
  236.     move.l    (sp)+,a6
  237.     rts
  238.  
  239. ;------------------
  240. ; End of macro.
  241. ;
  242. .ttr_end5:
  243.     endif
  244.     endm
  245.  
  246. ;------------------
  247.  
  248. ;------------------------------------------------------------------------------
  249. *
  250. * RestoreTDID_    Do Enable() and Permit() to go back to initial state.
  251. *
  252. ;------------------------------------------------------------------------------
  253.  
  254. ;------------------
  255. ; Macro
  256. ;
  257. RestoreTDID_        macro
  258.     ifd    ttr_RestoreTDID
  259.         bsr    ttr_RestoreTDId
  260.     else
  261.         pea    .ttr_end15(pc)
  262.  
  263. ;------------------
  264. ; Enable().
  265. ;
  266. ttr_RestoreTDID    =    *
  267.     move.l    a6,-(sp)
  268.     move.l    4.w,a6
  269.     jsr    -120(a6)        ;Disable()
  270.     jsr    -132(a6)        ;Forbid()
  271.     clr.w    294(a6)
  272.     jsr    -138(a6)        ;Permit()
  273.     jsr    -126(a6)        ;Enable()
  274.     move.l    (sp)+,a6
  275.     rts
  276.  
  277. ;------------------
  278. ; End of macro.
  279. ;
  280. .ttr_end15:
  281.     endif
  282.     endm
  283.  
  284. ;------------------
  285.  
  286. ;------------------------------------------------------------------------------
  287. *
  288. * SupervisorMode_    Enter supervisor mode in the old exec manner
  289. *
  290. * a5:            routine
  291. *
  292. ;------------------------------------------------------------------------------
  293. SupervisorMode_    MACRO
  294.         IFD    ttr_SupervisorMode
  295.         bsr    ttr_SupervisorMode
  296.         ELSE
  297.         pea    .ttr_SupervisorModeEnd(pc)
  298. ttr_SupervisorMode    EQU    *
  299.         movem.l    a5/a6,-(a7)
  300.         move.l    4.w,a6
  301.         jsr    -30(a6)
  302.         movem.l    (a7)+,a5/a6
  303.         rts
  304. .ttr_SupervisorModeEnd:
  305.         ENDC
  306.         ENDM
  307.  
  308.  
  309. ;------------------------------------------------------------------------------
  310. *
  311. * Supervisor_    Enter supervisor mode with supervisor stack. No regs changed.
  312. *        In case of a 68020+, the ISP is used, no matter what the
  313. *        M bit says.
  314. *
  315. * RESULT:    d0    Old SR. CCR is not guaranteed by Exec.
  316. *
  317. ;------------------------------------------------------------------------------
  318.  
  319. ;------------------
  320. ; Macro
  321. ;
  322. Supervisor_    macro
  323.     ifd    ttr_Supervisor
  324.         bsr    ttr_Supervisor
  325.     else
  326.         pea    .ttr_end6(pc)
  327.  
  328. ;------------------
  329. ; Clean up old stack
  330. ;
  331. ttr_Supervisor    =    *
  332.     pea    (a6)            ;    v    v
  333.     lea    .ttr_regs6(pc),a6    
  334.     movem.l    a4/a5,(a6)
  335.     movea.l    (sp)+,a4
  336.     movem.l    a4,8(a6)        ;ALL THIS DOES NOT CHANGE CCR
  337.     move.l    (sp)+,a4        ;where to go
  338.     movea.l    4.w,a6
  339.     lea    .ttr_super6(pc),a5    ;    ^    ^
  340.     jmp    -30(a6)            ;Supervisor()
  341.  
  342. ;------------------
  343. ; Supervisor routine.
  344. ; 
  345. .ttr_super6:
  346.     move.l    a4,2(a7)
  347.     move.w    (a7),d0
  348.     move.w    #$2000,(a7)
  349.     movem.l    .ttr_regs6(pc),a4-a6
  350.     rte
  351.  
  352. .ttr_regs6:
  353.     dc.l    0,0,0
  354.  
  355. ;------------------
  356. ; End of macro.
  357. ;
  358. .ttr_end6:
  359.     endif
  360.     endm
  361.  
  362. ;------------------
  363.  
  364. ;------------------------------------------------------------------------------
  365. *
  366. * User_        Return to user state.
  367. *
  368. ;------------------------------------------------------------------------------
  369.  
  370. ;------------------
  371. ; Macro
  372. ;
  373. User_    macro
  374.     andi.w    #$dfff,sr
  375.     endm
  376.  
  377. ;------------------
  378.  
  379. ;------------------------------------------------------------------------------
  380. *
  381. * PrevState_    Return to previous state.
  382. *
  383. * INPUT:    d0    Old SR register.
  384. *
  385. ;------------------------------------------------------------------------------
  386.  
  387. ;------------------
  388. ; Macro
  389. ;
  390. PrevState_    macro
  391.     move.w    d0,sr
  392.     endm
  393.  
  394. ;------------------
  395.  
  396. ;------------------------------------------------------------------------------
  397. *
  398. * GetSR_    Gets entier SR. If the CCR would be guaranteed for Supervisor()
  399. *        This routine could get a lot easier. No regs changed.
  400. *
  401. * RESULT:    d0    SR
  402. *
  403. ;------------------------------------------------------------------------------
  404.  
  405. ;------------------
  406. ; Macro
  407. ;
  408. GetSR_        macro
  409.     ifd    ttr_GetSR
  410.         bsr    ttr_GetSR
  411.     else
  412.         pea    .ttr_end7(pc)
  413.  
  414. ;------------------
  415. ; Get CCR, call supervisor and merge regs.
  416. ;
  417. ttr_GetSR    =    *
  418.     GetCCR_
  419.     andi.w    #$ff,d0        ;mask out CCR
  420.     move.w    d0,-(sp)    
  421.     Supervisor_
  422.     clr.b    d0        ;mask out SR
  423.     move.w    d0,sr
  424.     or.w    (sp)+,d0    ;=>SR
  425.     rts
  426.  
  427. ;------------------
  428. ; End of macro.
  429. ;
  430. .ttr_end7:
  431.     endif
  432.     endm
  433.  
  434. ;------------------
  435.  
  436. ;------------------------------------------------------------------------------
  437. *
  438. * GetCCR_    Gets CCR the right way. No regs changed.
  439. *
  440. * RESULT:    d0    CCR
  441. *
  442. ;------------------------------------------------------------------------------
  443.  
  444. ;------------------
  445. ; Macro
  446. ;
  447. GetCCR_        macro
  448.     ifd    ttr_GetCCR
  449.         bsr    ttr_GetCCR
  450.     else
  451.         pea    .ttr_end8(pc)
  452.  
  453. ;------------------
  454. ; Jump to right routine.
  455. ;
  456. ttr_GetCCR    =    *
  457.     movem.l    d1-d4,-(sp)
  458.     scs    d1    ;C
  459.     svs    d2    ;V
  460.     seq    d3    ;Z
  461.     smi    d4    ;N
  462.     roxl.b    #1,d0    ;X
  463.     roxr.b    #1,d4
  464.     roxl.b    #1,d0
  465.     roxr.b    #1,d3
  466.     roxl.b    #1,d0
  467.     roxr.b    #1,d2
  468.     roxl.b    #1,d0
  469.     roxr.b    #1,d1
  470.     roxl.b    #1,d0
  471.     and.w    #$1f,d0
  472.     movem.l    (sp)+,d1-d4
  473.     rts
  474.  
  475. ;------------------
  476. ; End of macro.
  477. ;
  478. .ttr_end8:
  479.     endif
  480.     endm
  481.  
  482. ;------------------
  483.  
  484. ;------------------------------------------------------------------------------
  485. *
  486. * FindTask_    Find task structure with Forbid()/Permit().
  487. *
  488. * INPUT:    a1    Name
  489. *
  490. * RESULT:    d0    Struct or 0
  491. *
  492. ;------------------------------------------------------------------------------
  493.  
  494. ;------------------
  495. ; Macro
  496. ;
  497. FindTask_        macro
  498.     ifd    ttr_FindTask
  499.         bsr    ttr_FindTask
  500.     else
  501.         pea    .ttr_end9(pc)
  502.  
  503. ;------------------
  504. ; Jump to right routine.
  505. ;
  506. ttr_FindTask    =    *
  507.     movem.l    d1-a6,-(sp)
  508.     Forbid_
  509.     move.l    4.w,a6
  510.     jsr    -294(a6)        ;FindTask()
  511.     Permit_
  512.     movem.l    (sp)+,d1-a6
  513.     rts    
  514.  
  515. ;------------------
  516. ; End of macro.
  517. ;
  518. .ttr_end9:
  519.     endif
  520.     endm
  521.     
  522. ;------------------
  523.  
  524. ;------------------------------------------------------------------------------
  525. *
  526. * FindName_    Find a node in a list, with Forbid()/Permit().
  527. *
  528. * INPUT:    a0    List
  529. *        a1    Name
  530. *
  531. * RESULT:    d0    Struct or 0
  532. *
  533. ;------------------------------------------------------------------------------
  534.  
  535. ;------------------
  536. ; Macro
  537. ;
  538. FindName_    macro
  539.     ifd    ttr_FindName
  540.         bsr    ttr_FindName
  541.     else
  542.         pea    .ttr_end10(pc)
  543.  
  544. ;------------------
  545. ; Jump to right routine.
  546. ;
  547. ttr_FindName    =    *
  548.     movem.l    d1-a6,-(sp)
  549.     Forbid_
  550.     move.l    4.w,a6
  551.     jsr    -276(a6)        ;FindName()
  552.     Permit_
  553.     movem.l    (sp)+,d1-a6
  554.     rts    
  555.  
  556. ;------------------
  557. ; End of macro.
  558. ;
  559. .ttr_end10:
  560.     endif
  561.     endm
  562.  
  563. ;------------------
  564.  
  565. ;------------------------------------------------------------------------------
  566. *
  567. * GetVBR_    Get the VBR register for 68010+. Returns 0 for 68000.
  568. *
  569. * RESULT:    d0    VBR or 0 for 68000.
  570. *
  571. ;------------------------------------------------------------------------------
  572.  
  573. ;------------------
  574. ; Macro
  575. ;
  576. GetVBR_    macro
  577.     ifd    ttr_GetVBR
  578.         bsr    ttr_GetVBR
  579.     else
  580.         pea    .ttr_end11(pc)
  581.  
  582. ;------------------
  583. ; Jump to right routine.
  584. ;
  585. ttr_GetVBR    =    *
  586.     movem.l    d1/a6,-(sp)
  587.     moveq    #0,d0
  588.     movea.l    4.w,a6
  589.     btst    #0,296+1(a6)        ;ATTN flags
  590.     beq.s    .ttr_GetVBRend
  591.  
  592.     Supervisor_
  593.     dc.w    $4e7a,$1801        ;movec    vbr,d1
  594.     PrevState_            ;return to previous mode
  595.     move.l    d1,d0
  596.  
  597. .ttr_GetVBRend:
  598.     movem.l    (sp)+,d1/a6
  599.     rts
  600.     
  601. ;------------------
  602. ; End of macro.
  603. ;
  604. .ttr_end11:
  605.     endif
  606.     endm
  607.  
  608. ;------------------
  609.  
  610. ;------------------------------------------------------------------------------
  611. *
  612. * ClearCaches_    Clear all caches. Does nothing for 68000/10.
  613. *
  614. ;------------------------------------------------------------------------------
  615.  
  616. ;------------------
  617. ; Macro
  618. ;
  619. ClearCaches_    macro
  620.     ifd    ttr_ClearCaches
  621.         bsr    ttr_ClearCaches
  622.     else
  623.         pea    .ttr_end12(pc)
  624.  
  625. ;------------------
  626. ; Jump to right routine.
  627. ;
  628. ttr_ClearCaches    =    *
  629.     movem.l    d0-d2/a0-a1/a6,-(sp)
  630.     movea.l    4.w,a6
  631.  
  632.     IFND    cws_V36PLUSONLY
  633.     btst    #1,296+1(a6)        ;ATTN flags
  634.     beq.s    .ttr_ClearCachesend    ;68000/10 => don't do
  635.     cmp.w    #36,20(a6)        ;2.0 or better?
  636.     bhs.s    .ttr_ClearCachesExec
  637.  
  638.     Supervisor_
  639.     dc.w    $4e7a,$1002        ;movec    cacr,d1
  640.     move.w    #$8000,d2
  641.     dc.w    $4e7b,$2002        ;movec    d2,cacr
  642.     dc.w    $4e7a,$2002        ;movec    cacr,d2
  643.     tst.w    d2
  644.     bmi.s    .ttr_CacheClearforty
  645.     or.w    #$808,d1        ;data and instruction cache clear
  646.     bra.s    .ttr_ClearCachesdone
  647.  
  648. .ttr_CacheClearforty:
  649.     dc.w    $f4f8            ;cpusha
  650.  
  651. .ttr_ClearCachesdone:
  652.     dc.w    $4e7b,$1002        ;movec    d1,cacr
  653.     PrevState_
  654.     bra.s    .ttr_ClearCachesend    
  655.     ENDIF
  656.  
  657. .ttr_ClearCachesExec:
  658.     jsr    -636(a6)        ;CacheClearU()
  659.  
  660. .ttr_ClearCachesend:
  661.     movem.l    (sp)+,d0-d2/a0-a1/a6
  662.     rts
  663.     
  664. ;------------------
  665. ; End of macro.
  666. ;
  667. .ttr_end12:
  668.     endif
  669.     endm
  670.  
  671. ;------------------
  672.  
  673. ;------------------------------------------------------------------------------
  674. *
  675. * DoRaw_    Call RawDoFmt.
  676. *
  677. *    a0:    format string
  678. *    a1:    data
  679. *    a3:    buffer
  680. *
  681. ;------------------------------------------------------------------------------
  682.  
  683. ;------------------
  684. ; Macro
  685. ;
  686. DoRaw_    macro
  687.     ifd    ttr_DoRaw
  688.         bsr    ttr_DoRaw
  689.     else
  690.         pea    .ttr_end13(pc)
  691.  
  692. ;------------------
  693. ; Jump to right routine.
  694. ;
  695. ttr_DoRaw    =    *
  696.     movem.l    d0-d3/a0-a3/a6,-(sp)
  697.     movea.l    4.w,a6
  698.     lea    .setin(pc),a2
  699.     jsr    -522(a6)        ;RawDOFmt()
  700.     movem.l    (sp)+,d0-d3/a0-a3/a6
  701.     rts
  702.  
  703. .setin:    move.b    d0,(a3)+
  704.     rts
  705.  
  706. ;------------------
  707. ; End of macro.
  708. ;
  709. .ttr_end13:
  710.     endif
  711.     endm
  712.  
  713. ;------------------
  714.  
  715. ;------------------------------------------------------------------------------
  716. *
  717. * DoRawCnt_    Count number of bytes used for the result string of DoRaw_.
  718. *
  719. *    a0:    format string
  720. *    a1:    data
  721. *
  722. ;------------------------------------------------------------------------------
  723.  
  724. ;------------------
  725. ; Macro
  726. ;
  727. DoRawCnt_    macro
  728.     ifd    ttr_DoRawCnt
  729.         bsr    ttr_DoRawCnt
  730.     else
  731.         pea    .ttr_end132(pc)
  732.  
  733. ;------------------
  734. ; Jump to right routine.
  735. ;
  736. ttr_DoRawCnt    =    *
  737.     movem.l    d1-d3/a0-a3/a6,-(sp)
  738.     lea    .counter(pc),a3
  739.     clr.l    (a3)
  740.     movea.l    4.w,a6
  741.     lea    .setin2(pc),a2
  742.     jsr    -522(a6)        ;RawDOFmt()
  743.     move.l    .counter(pc),d0
  744.     movem.l    (sp)+,d1-d3/a0-a3/a6
  745.     rts
  746.  
  747. .setin2:addq.l    #1,(a3)
  748.     rts
  749.  
  750. .counter:
  751.     dc.l    0
  752.  
  753. ;------------------
  754. ; End of macro.
  755. ;
  756. .ttr_end132:
  757.     endif
  758.     endm
  759.  
  760. ;------------------
  761.  
  762. ;------------------------------------------------------------------------------
  763. *
  764. * InitList_    Init a list.
  765. *
  766. * USAGE:    InitList_        Init list at a0.
  767. *        InitList_ (MyList)    Init MyList.
  768. *
  769. ;------------------------------------------------------------------------------
  770.  
  771. ;------------------
  772. ; Macro
  773. ;
  774. InitList_    macro
  775.     IFNC    '\1',''
  776.     lea    \1(pc),a0
  777.     ENDIF
  778.     ifd    ttr_InitList
  779.         bsr    ttr_InitList
  780.     else
  781.         pea    .ttr_end14(pc)
  782.  
  783. ;------------------
  784. ; Jump to right routine.
  785. ;
  786. ttr_InitList    =    *
  787.     pea    4(a0)
  788.     move.l    (sp)+,(a0)
  789.     clr.l    4(a0)
  790.     move.l    a0,8(a0)
  791.     rts
  792.  
  793. ;------------------
  794. ; End of macro.
  795. ;
  796. .ttr_end14:
  797.     endif
  798.     endm
  799.  
  800.  
  801. ;------------------
  802.  
  803. ;------------------------------------------------------------------------------
  804. *
  805. * SpaceKiller_    Standard space killer function for A0.
  806. *
  807. * USAGE:    SpaceKiller_
  808. *
  809. ;------------------------------------------------------------------------------
  810.  
  811. ;------------------
  812. ; Macro
  813. ;
  814. SpaceKiller_    macro
  815.     ifd    ttr_SpaceKiller
  816.         bsr    ttr_SpaceKiller
  817.     else
  818.         pea    .ttr_end16(pc)
  819.  
  820. ;------------------
  821. ; Jump to right routine.
  822. ;
  823. ttr_SpaceKiller    =    *
  824.     cmp.b    #" ",(a0)+
  825.     beq.s    ttr_SpaceKiller
  826.     subq.l    #1,a0
  827.     rts
  828.  
  829. ;------------------
  830. ; End of macro.
  831. ;
  832. .ttr_end16:
  833.     endif
  834.     endm
  835.  
  836. ;------------------
  837.  
  838.  
  839. ;------------------------------------------------------------------------------
  840. *
  841. * NoReq_    disable requesters, be 'quietly'
  842. * SetReq_    set pr_WindowPtr field
  843. * ResetReq_    set pr_WindowPtr field (SetReq_ = ResetReq_)
  844. *
  845. * NoReq_ returns old WindowPtr in d0.
  846. *
  847. * SetReq_ and ResetReq_ expect a value (for pr_WindowPtr) in d0.
  848. *
  849. ;------------------------------------------------------------------------------
  850.  
  851. ;------------------
  852. *
  853. * NoReq_
  854. *
  855. NoReq_    MACRO
  856.     IFD    ttr_NoReq
  857.         bsr    ttr_NoReq
  858.     ELSE
  859.         pea    .ttr_NoReqEnd(pc)
  860.  
  861. ;------------------
  862. ; NoReq().
  863. ttr_NoReq    EQU    *
  864.     movem.l    d1/a1,-(a7)
  865.     move.l    4.w,a1
  866.     move.l    $114(a1),a1        ; ThisTask
  867.     move.l    $b8(a1),d0        ; pr_WindowPtr
  868.     moveq    #-1,d1
  869.     move.l    d1,$b8(a1)        ; pr_WindowPtr
  870.     movem.l    (a7)+,d1/a1
  871.     rts
  872. .ttr_NoReqEnd:
  873.     ENDC
  874.     ENDM
  875.  
  876.  
  877.  
  878.  
  879.  
  880. ;------------------
  881. *
  882. * SetReq_
  883. *
  884. SetReq_    MACRO
  885.     IFD    ttr_SetReq
  886.         bsr    ttr_SetReq
  887.     ELSE
  888.         pea    .ttr_SetReqEnd(pc)
  889.  
  890. ;------------------
  891. ; SetReq().
  892. ttr_SetReq    EQU    *
  893.     move.l    a1,-(a7)
  894.     move.l    4.w,a1
  895.     move.l    $114(a1),a1        ; ThisTask
  896.     move.l    d0,$b8(a1)        ; pr_WindowPtr
  897.     move.l    (a7)+,a1
  898.     rts
  899. .ttr_SetReqEnd:
  900.     ENDC
  901.     ENDM
  902.  
  903.  
  904.  
  905. ;------------------
  906. *
  907. * RestoreReq_
  908. *
  909. RestoreReq_    MACRO
  910.     SetReq_
  911.     ENDM
  912.  
  913.  
  914.  
  915.  
  916. ;--------------------------------------------------------------------
  917.  
  918. ;------------------
  919.     base    ttr_oldbase
  920.  
  921. ;------------------
  922.     endif
  923.  
  924.     end
  925.  
  926.